Browse Source

gettext: add new package

master
André Silva 5 months ago
parent
commit
616fcbff58
2 changed files with 111 additions and 0 deletions
  1. +57
    -0
      gettext/PKGBUILD
  2. +54
    -0
      gettext/remove-support-for-running-java-bytecode.patch

+ 57
- 0
gettext/PKGBUILD View File

@@ -0,0 +1,57 @@
# Maintainer (Arch):
# Maintainer: André Silva <emulatorman@hyperbola.info>
# Maintainer: Márcio Silva <coadde@hyperbola.info>

pkgname=gettext
pkgver=0.19.8.1
_debver=0.19.8.1
_debrel=2+deb9u1
pkgrel=2.hyperbola5
pkgdesc="GNU internationalization library, without support for running Java bytecode"
arch=('i686' 'x86_64')
url="https://www.gnu.org/software/gettext/"
license=('GPL-3')
groups=('base' 'base-devel')
depends=('gcc-libs' 'acl' 'sh' 'glib2' 'libunistring')
makedepends=('quilt')
optdepends=('git: for autopoint infrastructure updates')
options=(!docs)
source=(https://ftp.gnu.org/pub/gnu/gettext/${pkgname}-${pkgver}.tar.gz{,.sig}
https://deb.debian.org/debian/pool/main/g/gettext/gettext_$_debver-$_debrel.debian.tar.xz
remove-support-for-running-java-bytecode.patch)
validpgpkeys=('462225C3B46F34879FC8496CD605848ED7E69871') # Daiki Ueno

prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
# Debian patches
export QUILT_PATCHES=debian/patches
export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
export QUILT_DIFF_ARGS='--no-timestamps'

mv "$srcdir"/debian .

# Doesn't apply and seems unimportant
rm -v debian/patches/01-do-not-use-java-in-urlget || true

quilt push -av
fi
# Remove support for running Java bytecode
patch -p1 -i ../remove-support-for-running-java-bytecode.patch
}

build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr
make
}

package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
sha512sums=('073042fa2dc48804c58e76f036130a669e19612c25427b0ab14d0b366b549a63751bf3af03bfd0745d7c4f72497a4b2aab26a3cc6de83189ce111679073878e1'
'SKIP'
'029a1363923a9d872aee70cdcc2f5af611ad318917aef7ea195696bb4f1cab71fa367897f846f297964d8408dadc1886425fabb5d0b8e67ad449e90b690ea8df'
'27ac154255ac46ccf18ad310834825627a4cc32d7a0afd217059ee89a3e083b0fe941126ec7b6ac4d5b04e1afdce0ed7e45584a5f5837c48dfaaa17e3ae3c0be')

+ 54
- 0
gettext/remove-support-for-running-java-bytecode.patch View File

@@ -0,0 +1,54 @@
diff --git a/gettext-tools/gnulib-lib/Makefile.gnulib b/gettext-tools/gnulib-lib/Makefile.gnulib
index 438bf9d..cc3a5aa 100644
--- a/gettext-tools/gnulib-lib/Makefile.gnulib
+++ b/gettext-tools/gnulib-lib/Makefile.gnulib
@@ -1134,9 +1134,9 @@ EXTRA_DIST += $(top_srcdir)/../build-aux/javaexec.sh.in
## begin gnulib module javaversion
libgettextlib_la_SOURCES += javaversion.h javaversion.c
-pkgdata_DATA += javaversion.class
+pkgdata_DATA +=
-EXTRA_DIST += javaversion.class javaversion.java
+EXTRA_DIST +=
## end gnulib module javaversion
diff --git a/gettext-tools/gnulib-lib/Makefile.in b/gettext-tools/gnulib-lib/Makefile.in
index a8e89eb..1c64cda 100644
--- a/gettext-tools/gnulib-lib/Makefile.in
+++ b/gettext-tools/gnulib-lib/Makefile.in
@@ -2134,8 +2134,8 @@ EXTRA_DIST = acl-internal.h acl.h acl_entries.c alignof.h alloca.in.h \
isnan.c isnanf-nolibm.h isnanf.c float+.h isnan.c isnanl.c \
float+.h isnan.c isnanl-nolibm.h isnanl.c iswblank.c \
$(top_srcdir)/../build-aux/javacomp.sh.in \
- $(top_srcdir)/../build-aux/javaexec.sh.in javaversion.class \
- javaversion.java langinfo.in.h libcroco/cr-additional-sel.c \
+ $(top_srcdir)/../build-aux/javaexec.sh.in \
+ langinfo.in.h libcroco/cr-additional-sel.c \
libcroco/cr-additional-sel.h libcroco/cr-attr-sel.c \
libcroco/cr-attr-sel.h libcroco/cr-cascade.c \
libcroco/cr-cascade.h libcroco/cr-declaration.c \
@@ -2357,7 +2357,7 @@ noinst_LTLIBRARIES = $(am__append_10) $(am__append_15) \
# Extra files to be installed.
gettextsrcdir = $(datadir)/gettext
gettextsrc_DATA = gettext.h
-pkgdata_DATA = javaversion.class
+pkgdata_DATA =
# Hmm... is this still necessary?
# Needed so that config.h and woe32dll/export.h are found.
diff --git a/gettext-tools/gnulib-m4/gnulib-comp.m4 b/gettext-tools/gnulib-m4/gnulib-comp.m4
index 7161673..1b4b7dd 100644
--- a/gettext-tools/gnulib-m4/gnulib-comp.m4
+++ b/gettext-tools/gnulib-m4/gnulib-comp.m4
@@ -1743,9 +1743,7 @@ AC_DEFUN([gl_FILE_LIST], [
lib/javaexec.c
lib/javaexec.h
lib/javaversion.c
- lib/javaversion.class
lib/javaversion.h
- lib/javaversion.java
lib/langinfo.in.h
lib/libcroco/cr-additional-sel.c
lib/libcroco/cr-additional-sel.h

Loading…
Cancel
Save